Tag: bno055

How to Capture Roll, Pitch, and Yaw Data Using Raspberry Pi and Arduino

In this post, I’ll show you how to capture roll, pitch, and yaw data using Raspberry Pi and Arduino.

Requirements

Here are the requirements:

  • Using the IMU connected to the Arduino, capture roll, pitch, and yaw data.
  • Send the data via Serial over USB to the Raspberry Pi.
  • Send the data via WiFi from Raspberry Pi to my host computer (e.g. my personal laptop).
  • Display the data on my host computer.
  • On the Arduino, use FreeRTOS for tasks.
  • To make things interesting, I mounted the IMU on a quadcopter.

Design

Hardware

The following components are used in this project. You will need:

Software

Here are the steps for the software of the system:

  • Define two tasks for Blink & IMURead. These are function prototypes.
    • The Blink task blinks the built-in LED on the Arduino board.
    • IMURead captures Roll+Pitch+Yaw data from the Adafruit BNO055.
  • Define a method that displays some basic information on the sensor.
  • Define a method that displays some basic information about the sensor status.
  • Define a method that displays the sensor calibration status.
  • Setup Function:
    • Initialize serial communication at 9600 bits per second
    • Wait for serial port to connect (Needed for native USB, on LEONARDO, MICRO, YUN, and other 32u4 based boards).
    • Initialize the sensor.
    • Display some basic information on this sensor.
    • Set up two tasks to run independently.
  • Empty loop since things are done in tasks.

Implementation

I began by testing the Adafruit BNO055 Absolute Orientation Sensor. The BNO055 is three sensors in one device. It includes an accelerometer to measure acceleration forces, a gyroscope that uses Earth’s gravity to help determine orientation, and a magnetometer that measures magnetism. Typical applications of this sensor include navigation, robotics, fitness, augmented reality, and tablet computers.

To setup the BNO055, I first need to prepare the header strip by cutting it to an appropriate length and placing it into the breadboard. I placed the long pins down.

I then added the BNO055 board on top of the pins.

I then soldered all of the pins in order to solidify electrical contact. Here are the steps I took:

  • I put on safety glasses and latex gloves.
  • I turned on the USB fan for ventilation, in order to to breathe in the smoke.
  • I turned on the soldering iron to the 4 heat setting.
  • I placed a damp sponge in the soldering station.
  • Once the iron was hot, I tinned the tip by adding a little bit of solder to cover the tip.
  • I wiped the tip off on the damp sponge to remove all but a thin layer of solder to help the tip last longer and to facilitate the transfer of heat from the soldering iron to the joint.
  • I placed the tip of the soldering iron to the joint to heat it up.
  • I fed a small amount of solder to the joints and removed the soldering iron after 2 seconds in order to not damage the board.
  • With the soldering iron hot, I wiped it off on a damp sponge.
  • I turned off the soldering iron and cleaned everything up.

I wired the BNO055 to the Arduino Uno using the solderless breadboard:

  • Connected Vin to the power supply of 5V
  • Connected GND to common power/data ground
  • Connected the SDA pin to the I2C data SDA pin on the Arduino (A4).
  • Connected the SCL pin to the I2C clock SCL pin on the Arduino (A5).
roll_pitch_yaw_1

Next, I attached the Arduino Uno to the USB port on my computer.

I opened the Library manager and installed the Adafruit_BNO055 driver which supports reading raw sensor data and the Adafruit Unified Sensor system to retrieve orientation data in a standard data format.

I used the Adafruit Sensor System code in order to retrieve the three axis orientation data.

To test the Unified Sensor System output, I opened and ran the sensorapi demo in the Adafruit_BNO055 examples folder.

I also opened and ran the rawdata demo in the Adafruit_BNO055 examples folder.

I opened the Sensor API and redefined the X, Y, and Z variables to Roll, Pitch, Yaw. I assumed that the front of the BNO055 was the part of the sensor labeled BNO055.

I used this website for the assumptions in order to determine which of the variables corresponded to Roll, Pitch, and Yaw. In my analysis, I found that Yaw = X, Pitch = Y, and Roll = Z. I determined this by rotating the BNO055 board around to 90 degrees yaw (East direction), then roll (full roll to the right), and then pitch (BNO055 pointing straight up at the sky), and observing which variable changed to 90 degrees.

I successfully tested the BNO055. It worked properly. Here was the output from the Serial monitor.

roll_pitch_yaw_2

I need to use FreeRTOS for the tasks in the Arduino code for the BNO055.

I opened up Arduino on my desktop computer. I then went to Sketch -> Manage Libraries and looked for FreeRTOS, and installed it.

roll_pitch_yaw_3

Then, I went under the Sketch->Include Library menu to ensure that the FreeRTOS library is included in my sketch.

roll_pitch_yaw_4

I then compiled and upload this empty sketch to my Arduino Uno.

FreeRTOS was now running on my device.

Then I uploaded and tested the example Blink sketch. It is under File -> Examples -> 01.Basics. I inserted #include <Arduino_FreeRTOS.h> at the start of the sketch. I then compiled it and uploaded it to the Arduino Uno.

Then I uploaded and tested the example Blink_AnalogRead.ino sketch. It is under File -> Examples -> FreeRTOS. I made sure #include <Arduino_FreeRTOS.h> was inserted at the start of the sketch. I then compiled it and uploaded it to the Arduino Uno. This sketch combines two basic Arduino examples, Blink and AnalogRead into one sketch with two separate tasks. Both tasks perform their duties independently, managed by the FreeRTOS scheduler.

Next, I downloaded Arduino to my Raspberry Pi. It took me a while to do this since a lot of the blogs and YouTube videos had incorrect instructions. I’ll walk you through everything I did below.

I first followed these steps. This process will enable me to execute the Arduino-Raspberry Pi serial communication.

roll_pitch_yaw_5

I right clicked on the extracted folder and click on open in terminal.

I then typed the below command in the terminal to install the Arduino IDE.

sudo ./install.sh

An error message showed up, which was ignored. The Arduino IDE was supposedly installed.

roll_pitch_yaw_6

I then typed the following command to open up the Arduino IDE

sudo ./arduino

Nothing opened up. This installation attempt failed.

So now, I tried an alternative way of installing Arduino. I typed the following commands as recommended here.

sudo apt-get update && sudo apt-get upgrade
sudo apt-get install arduino

I then restarted the Raspberry Pi.

Still the Arduino IDE would not start. Maybe third time’s a charm.

I then went to the Arduino website and went under “Hourly Builds”. I clicked on “Linux ARM.” I followed these instructions:

I then went to the /home/pi/Downloads folder.

I right clicked on the tar.xz folder and I clicked “Archiver.” I then selected “All Files” and clicked “Extract.”

roll_pitch_yaw_7

I typed the following commands in the terminal window.

cd Downloads
ls
cd arduino-nightly
ls
./install.sh
sudo ./install.sh

I then went to Raspberry Pi in the upper left corner of the screen. Programming -> Arduino IDE.

The Arduino IDE successfully loaded!

roll_pitch_yaw_8

With the Arduino plugged in to the Raspberry Pi USB port, I tried the example Blink sketch under File -> Examples -> 01.Basics in the Arduino IDE. The LED on the Arduino began to blink.

I then opened the Library manager and installed the Adafruit_BNO055 driver which supports reading raw sensor data and the Adafruit Unified Sensor system to retrieve orientation data in a standard data format.

I then went to Sketch -> Manage Libraries and looked for FreeRTOS, and installed it.

To test the Unified Sensor System output, I opened and ran the sensorapi demo in the Adafruit_BNO055 examples folder.

I opened the sensorapi example sketch and redefined the X, Y, and Z variables to Roll, Pitch, Yaw. I assumed that the front of the BNO055 was the part of the sensor labeled BNO055.

I then modified the sensorapi sketch in the Arduino IDE in order to incorporate FreeRTOS.

I also created two tasks so that I could use FREERTOS and get experience with an RTOS.

  • The Blink task blinks the built-in LED on the Arduino board.
  • IMURead captures Roll+Pitch+Yaw data from the Adafruit BNO055.

Hardware

roll_pitch_yaw_9
roll_pitch_yaw_10
roll_pitch_yaw_11
roll_pitch_yaw_12

Software

Here is the code for the program I developed. (Note that after you load the sketch to Arduino, the code runs automatically whenever the Arduino is connected to power. That could be via a battery or power directly from the Raspberry Pi):

#include <Arduino_FreeRTOS.h>
#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BNO055.h>
#include <utility/imumaths.h>

/* This driver uses the Adafruit unified sensor library (Adafruit_Sensor),
   which provides a common 'type' for sensor data and some helper functions.

   To use this driver you will also need to download the Adafruit_Sensor
   library and include it in your libraries folder.

   You should also assign a unique ID to this sensor for use with
   the Adafruit Sensor API so that you can identify this particular
   sensor in any data logs, etc.  To assign a unique ID, simply
   provide an appropriate value in the constructor below (12345
   is used by default in this example).

   Connections
   ===========
   Connect SCL to analog 5
   Connect SDA to analog 4
   Connect VDD to 3-5V DC
   Connect GROUND to common ground

   History
   =======
   2015/MAR/03  - First release (KTOWN)
   2015/AUG/27  - Added calibration and system status helpers


   In this program, we use the Adafruit BNO055 connected to the Arduino to capture
   Roll+Pitch+Yaw data.

   @author Addison Sears-Collins
   @version 1.0 2019-04-02
*/

Adafruit_BNO055 bno = Adafruit_BNO055(55);

// Define two tasks for Blink & IMURead. These are function prototypes.
// The Blink task blinks the built-in LED on the Arduino board.
// IMURead captures Roll+Pitch+Yaw data from the Adafruit BNO055.
void TaskBlink( void *pvParameters );
void TaskIMURead( void *pvParameters );


/*--------------------------------------------------*/
/*---------------------- Tasks ---------------------*/
/*--------------------------------------------------*/

void TaskBlink(void *pvParameters)  // This is a task.
{
  (void) pvParameters;

/*
  Blink
  Turns on an LED on for one second, then off for one second, repeatedly.

  Most Arduinos have an on-board LED you can control. On the UNO, LEONARDO, MEGA, and ZERO 
  it is attached to digital pin 13, on MKR1000 on pin 6. LED_BUILTIN takes care 
  of use the correct LED pin whatever is the board used.
  
  The MICRO does not have a LED_BUILTIN available. For the MICRO board please substitute
  the LED_BUILTIN definition with either LED_BUILTIN_RX or LED_BUILTIN_TX.
  e.g. pinMode(LED_BUILTIN_RX, OUTPUT); etc.
  
  If you want to know what pin the on-board LED is connected to on your Arduino model, check
  the Technical Specs of your board  at https://www.arduino.cc/en/Main/Products
  
  This example code is in the public domain.

  modified 8 May 2014
  by Scott Fitzgerald
  
  modified 2 Sep 2016
  by Arturo Guadalupi
*/

  // initialize digital LED_BUILTIN on pin 13 as an output.
  pinMode(LED_BUILTIN, OUTPUT);

  for (;;) // A Task shall never return or exit.
  {
    digitalWrite(LED_BUILTIN, HIGH);   // turn the LED on (HIGH is the voltage level)
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
    digitalWrite(LED_BUILTIN, LOW);    // turn the LED off by making the voltage LOW
    vTaskDelay( 1000 / portTICK_PERIOD_MS ); // wait for one second
  }
}

void TaskIMURead(void *pvParameters)  // This is a task.
{
  (void) pvParameters;
  
/*
  IMUReadSerial
  Capture the Roll+Pitch+Yaw data

*/

  for (;;)
  {
    // Get a new sensor event
    sensors_event_t event;
    bno.getEvent(&event);
   
    /* Display the floating point data */
    Serial.print("Yaw: ");
    Serial.print(event.orientation.x, 4);
    Serial.print("\tPitch: ");
    Serial.print(event.orientation.y, 4);
    Serial.print("\tRoll: ");
    Serial.print(event.orientation.z, 4);

    /* Optional: Display calibration status */
    displayCalStatus();

    /* Optional: Display sensor status (debug only) */
    //displaySensorStatus();

    /* New line for the next sample */
    Serial.println("");
    
    vTaskDelay(7);  // seven tick delay (105ms) in between reads for stability
  }
}

/**************************************************************************/
/*
    Displays some basic information on this sensor from the unified
    sensor API sensor_t type (see Adafruit_Sensor for more information)
*/
/**************************************************************************/
void displaySensorDetails(void)
{
  sensor_t sensor;
  bno.getSensor(&sensor);
  Serial.println("------------------------------------");
  Serial.print  ("Sensor:       "); Serial.println(sensor.name);
  Serial.print  ("Driver Ver:   "); Serial.println(sensor.version);
  Serial.print  ("Unique ID:    "); Serial.println(sensor.sensor_id);
  Serial.print  ("Max Value:    "); Serial.print(sensor.max_value); Serial.println(" xxx");
  Serial.print  ("Min Value:    "); Serial.print(sensor.min_value); Serial.println(" xxx");
  Serial.print  ("Resolution:   "); Serial.print(sensor.resolution); Serial.println(" xxx");
  Serial.println("------------------------------------");
  Serial.println("");
  delay(500);
}

/**************************************************************************/
/*
    Display some basic info about the sensor status
*/
/**************************************************************************/
void displaySensorStatus(void)
{
  /* Get the system status values (mostly for debugging purposes) */
  uint8_t system_status, self_test_results, system_error;
  system_status = self_test_results = system_error = 0;
  bno.getSystemStatus(&system_status, &self_test_results, &system_error);

  /* Display the results in the Serial Monitor */
  Serial.println("");
  Serial.print("System Status: 0x");
  Serial.println(system_status, HEX);
  Serial.print("Self Test:     0x");
  Serial.println(self_test_results, HEX);
  Serial.print("System Error:  0x");
  Serial.println(system_error, HEX);
  Serial.println("");
  delay(500);
}

/**************************************************************************/
/*
    Display sensor calibration status
*/
/**************************************************************************/
void displayCalStatus(void)
{
  /* Get the four calibration values (0..3) */
  /* Any sensor data reporting 0 should be ignored, */
  /* 3 means 'fully calibrated" */
  uint8_t system, gyro, accel, mag;
  system = gyro = accel = mag = 0;
  bno.getCalibration(&system, &gyro, &accel, &mag);

  /* The data should be ignored until the system calibration is > 0 */
  Serial.print("\t");
  if (!system)
  {
    Serial.print("! ");
  }

  /* Display the individual values */
  Serial.print("Sys:");
  Serial.print(system, DEC);
  Serial.print(" G:");
  Serial.print(gyro, DEC);
  Serial.print(" A:");
  Serial.print(accel, DEC);
  Serial.print(" M:");
  Serial.print(mag, DEC);
}

/*--------------------------------------------------*/
/*--------------------Setup and Loop----------------*/
/*--------------------------------------------------*/
// The setup function runs once when you press reset or power the board
void setup() {
  
  // Initialize serial communication at 9600 bits per second.
  Serial.begin(9600);
  
  while (!Serial) {
    ; // Wait for serial port to connect. Needed for native USB, on LEONARDO, MICRO, YUN, and other 32u4 based boards.
  }

  Serial.println("Orientation Sensor Test"); Serial.println("");

  /* Initialize the sensor */
  if(!bno.begin())
  {
    /* There was a problem detecting the BNO055 ... check your connections */
    Serial.print("Ooops, no BNO055 detected ... Check your wiring or I2C ADDR!");
    while(1);
  }

  delay(1000);

  /* Display some basic information on this sensor */
  displaySensorDetails();

  /* Optional: Display current status */
  displaySensorStatus();

  bno.setExtCrystalUse(true);
  
  // Set up two tasks to run independently.
  xTaskCreate(
    TaskBlink
    ,  (const portCHAR *)"Blink"   // A name just for humans
    ,  128  // This stack size can be checked & adjusted by reading the Stack Highwater
    ,  NULL
    ,  1  // Priority, with 3 (configMAX_PRIORITIES - 1) being the highest, and 0 being the lowest.
    ,  NULL );

  xTaskCreate(
    TaskIMURead
    ,  (const portCHAR *) "IMURead"
    ,  128  // Stack size
    ,  NULL
    ,  2  // Priority
    ,  NULL );

  // Now the task scheduler, which takes over control of scheduling individual tasks, is automatically started.
}

void loop()
{
  // Empty. Things are done in Tasks.
}

Video

Setting up the BNO055 Absolute Orientation Sensor

Video Transcript

In this video, we’ll set up the Adafruit BNO055 Absolute Orientation Sensor from scratch, step-by-step.

The BNO055 is actually three sensors in one device. It includes an accelerometer to measure acceleration forces, a gyroscope that uses Earth’s gravity to help determine orientation, and a magnetometer that measures magnetism. Typical applications of this sensor include navigation, robotics, fitness, augmented reality, and tablet computers.

By the end of this video, you will have all of the hardware and software of the BNO055 sensor set up and ready to go so you can measure the roll, pitch, and yaw of an aerial electronic device, such as a drone.

Ok, let’s get started. Feel free to pause the video at any time as you follow along with me.

You will need:

To begin, get your BNO055 IMU board, the header strip, and the solderless breadboard. Lay them out on a table.

Prepare the header strip by cutting it to an appropriate length and placing it into the breadboard. You want a piece with 4 pins and a piece with 6 pins so that they can fit into the holes on the BNO055 board.
Place the long pins down into the solderless breadboard.

Next place the BNO055 board on top of the pins.

We will now solder all of the pins to the BNO055 in order to solidify electrical contact:

  • Gather all the materials presented earlier in the video, and lay them out on a table.
  • If you have safety glasses and latex gloves, put them on. Eyeglasses are fine.
  • Turn on the USB fan for ventilation, in order to avoid breathing in the soldering smoke.
  • Turn on the soldering iron to the 4 heat setting.
  • Lay your damp sponge in the center of the silicon mat.
  • Once the iron is hot, tin the tip by adding a little bit of solder to cover the tip.
  • Now wipe the tip off on the damp sponge to remove all but a thin layer of solder to help the tip last longer and to facilitate the transfer of heat from the soldering iron to the joint.
  • Place the tip of the soldering iron to the joint, where the header pin and board meet, to heat it up.
  • Feed a small amount of solder to the joint and remove the soldering iron after 2 seconds in order to not damage the board. Do this for all the pins in the BNO055.
  • OK, we are done soldering. With the soldering iron hot, wipe it off on a damp sponge.
  • Turn off the soldering iron and clean everything up.

With the BNO055 all cooled off, we need to wire the BNO055 to the Arduino Uno using the solderless breadboard. Here are the connections we need to make.

  • Connect Vin of the BNO055 to the power supply of 5V on the Arduino
  • Connect GND of the BNO055 to GND on the Arduino
  • Connect the SDA pin of the BNO055 to the SDA pin of the Arduino, which is A4.
  • Connect the SCL pin of the BNO055 to the SCL pin of the Arduino, which is A5.

Next, we attach the Arduino Uno to the USB port on our main desktop computer.

Now, on our desktop computer, we open Arduino.

We navigate to the Library manager and install two libraries:

  1. The Adafruit Unified Sensor system library to retrieve orientation data in a standard data format, and…
  2. The Adafruit_BNO055 driver, which supports reading raw sensor data.

Now, go to File -> Examples -> Adafruit BNO055, and click sensorapi. The Arduino sketch that pops up is a demo that will help us test the BNO055.

First double check the Arduino is properly connected to your desktop computer by going to Tools -> Port. Make sure the Arduino/Genuino Uno has a checkmark next to it.

Now, let’s run the demo. Save the sensorapi sketch, compile it by clicking the checkmark, and upload it to the Arduino by clicking the right arrow button.

Once it is finished uploading, open the Serial monitor by clicking the magnifying glass in the upper right corner. We see the x, y, and z orientation data flowing in real-time.

However, we want Roll, Pitch, Yaw data and not X, Y, Z. So we need to change X, Y, and Z to Roll, Pitch, Yaw.

I’m going to use this website to refresh myself what roll, pitch, and yaw are.

Yaw is movement from side to side. Like when you shake your head “no.”

Pitch is movement up and down. Like when you nod your head “yes.”

Roll is movement from left to right. Like when you tilt your head from side to side.

Ok, let’s start the sensorapi program up again and see what happens to the X, Y, and Z values when we move the BNO055 board around, in different orientations. The front of the BNO055 board is labeled BNO055. 

We rotate the BNO055 board around to 90 degrees yaw in the East direction. I see the X value changes. Then we roll the board to the right. The Z value changes. I then pitch the board by pointing the board straight up at the sky. The Y value changes.  So there we have it. Yaw is X, Roll is Z, and Pitch is Y.

We go to the sensorapi code and modify it accordingly so that we use the terms Yaw, Roll, and Pitch, instead of X, Z, and Y, respectively.

Let’s compile and upload the program again to make sure everything is working properly. Here is the output of the Serial monitor.

Ok. That completes this video. You are now ready to use your BNO055.